ayatana-commits team mailing list archive

[Ted Gould <ted@xxxxxxxx>]

Ted Gould has proposed merging lp:~ted/indicator-datetime/gtk3-transition into lp:indicator-datetime.

Requested reviews:
  Indicator Applet Developers (indicator-applet-developers)


A stab at what it'll take to migrate this indicator to GTK3.  A test case for what we'll need for all indicators.
-- 
https://code.launchpad.net/~ted/indicator-datetime/gtk3-transition/+merge/40690
Your team ayatana-commits is subscribed to branch lp:indicator-datetime.

=== modified file 'configure.ac'
--- configure.ac	2010-10-07 21:15:08 +0000
+++ configure.ac	2010-11-12 04:42:39 +0000
@@ -23,12 +23,31 @@
 
 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
 
+AC_ARG_ENABLE([deprecations],
+  [AS_HELP_STRING([--enable-deprecations],
+    [allow deprecated API usage @<:@default=yes@:>@])],
+  [],
+  [enable_deprecations=yes])
+AS_IF([test "x$enable_deprecations" = xno],
+  [CFLAGS="$CFLAGS -DG_DISABLE_DEPRECATED -DGDK_DISABLE_DEPRECATED -DGDK_PIXBUF_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED -DGSEAL_ENABLE -DGTK_DISABLE_SINGLE_INCLUDES"]
+)
+
 AC_PATH_PROG([GLIB_MKENUMS], [glib-mkenums])
 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
 
 PKG_PROG_PKG_CONFIG
 
 ###########################
+# GTK+ version option
+###########################
+
+AC_ARG_WITH([gtk],
+  [AS_HELP_STRING([--with-gtk],
+    [Which version of gtk to use @<:@default=2@:>@])],
+  [],
+  [with_gtk=2])
+
+###########################
 # Dependencies
 ###########################
 
@@ -41,9 +60,23 @@
 GEOCLUE_REQUIRED_VERSION=0.12.0
 OOBS_REQUIRED_VERSION=2.31.0
 
-PKG_CHECK_MODULES(INDICATOR, indicator >= $INDICATOR_REQUIRED_VERSION
+AS_IF([test "x$with_gtk" = x3],
+    [PKG_CHECK_MODULES(INDICATOR, indicator3 >= $INDICATOR_REQUIRED_VERSION
+                                  dbusmenu-glib >= $DBUSMENUGLIB_REQUIRED_VERSION
+                                  dbusmenu-gtk3 >= $DBUSMENUGTK_REQUIRED_VERSION
+                                  libido3-0.1 >= $INDICATOR_DISPLAY_OBJECTS)
+        ],
+      [test "x$with_gtk" = x2],
+    [PKG_CHECK_MODULES(INDICATOR, indicator >= $INDICATOR_REQUIRED_VERSION
+                                  dbusmenu-glib >= $DBUSMENUGLIB_REQUIRED_VERSION
+                                  dbusmenu-gtk >= $DBUSMENUGTK_REQUIRED_VERSION
+                                  libido-0.1 >= $INDICATOR_DISPLAY_OBJECTS)
+        ],
+    [AC_MSG_FAILURE([Value for --with-gtk was neither 2 nor 3])]
+)
+
+PKG_CHECK_MODULES(SERVICE,   indicator >= $INDICATOR_REQUIRED_VERSION
                              dbusmenu-glib >= $DBUSMENUGLIB_REQUIRED_VERSION
-                             dbusmenu-gtk >= $DBUSMENUGTK_REQUIRED_VERSION
                              libido-0.1 >= $INDICATOR_DISPLAY_OBJECTS
                              gio-2.0 >= $GIO_REQUIRED_VERSION
                              geoclue >= $GEOCLUE_REQUIRED_VERSION
@@ -52,6 +85,9 @@
 AC_SUBST(INDICATOR_CFLAGS)
 AC_SUBST(INDICATOR_LIBS)
 
+AC_SUBST(SERVICE_CFLAGS)
+AC_SUBST(SERVICE_LIBS)
+
 ###########################
 # Grab the GSettings Macros
 ###########################
@@ -69,13 +105,21 @@
 # Indicator Info
 ###########################
 
-if test "x$with_localinstall" = "xyes"; then
+AS_IF([test "x$with_localinstall" = "xyes"],
+	[
 	INDICATORDIR="${libdir}/indicators/2/"
 	INDICATORICONSDIR="${datadir}/libindicate/icons/"
-else
-	INDICATORDIR=`$PKG_CONFIG --variable=indicatordir indicator`
-	INDICATORICONSDIR=`$PKG_CONFIG --variable=iconsdir indicator`
-fi
+	],
+	[AS_IF([test "x$with_gtk" = "x2"],
+		[
+		INDICATORDIR=`$PKG_CONFIG --variable=indicatordir indicator`
+		INDICATORICONSDIR=`$PKG_CONFIG --variable=iconsdir indicator`
+		],
+		[
+		INDICATORDIR=`$PKG_CONFIG --variable=indicatordir indicator3`
+		INDICATORICONSDIR=`$PKG_CONFIG --variable=iconsdir indicator3`
+		])])
+
 AC_SUBST(INDICATORDIR)
 AC_SUBST(INDICATORICONSDIR)
 

=== modified file 'src/Makefile.am'
--- src/Makefile.am	2010-09-07 17:44:33 +0000
+++ src/Makefile.am	2010-11-12 04:42:39 +0000
@@ -12,10 +12,10 @@
 indicator_datetime_service_CFLAGS = \
 	-Wall \
 	-Werror \
-	$(INDICATOR_CFLAGS) \
+	$(SERVICE_CFLAGS) \
 	-DTIMEZONE_FILE="\"/etc/timezone\""
 indicator_datetime_service_LDADD = \
-	$(INDICATOR_LIBS)
+	$(SERVICE_LIBS)
 
 datetimelibdir = $(INDICATORDIR)
 datetimelib_LTLIBRARIES = libdatetime.la