kicad-developers team mailing list archive

[Nick Østergaard <oe.nick@xxxxxxxxx>]

>>> I've only tested this on windows so please let me know if you find any
>>> issues on other platforms.  For those of you who are using the msys2
>>> package builder file PKGBUILD to build kicad, please note that the msys2
>>> version of bzr is broken and will fail attempting to determine the bzr
>>> version.  Please comment out the bzr source build dependency in PKGBUILD
>>> and use one of the native bzr windows installers instead.  Make sure to
>>> add the bzr executable to your system path so CMake can find it during
>>> configuration.  I will remove it from the PKGBUILD file and send a pull
>>> request to the msys2 devs when I get a chance.
>>
>> The PKGBUILD I am using is using git, because that is what the initial
>> PKGBUILD was based upon, and git has proven much easier to work with
>> in this regard too... bzr is very slow.
>>
>> With this I am currently patching the version string to calculate BZR
>> version string and also list the short git commit hash.
>>
>> Are you interested in merging this patch by now?  It will also help
>> other people using git to build with.  I guess I will have to apply
>> the new logic from CreateBzrVersionHeader.cmake to my
>> CreateGitVersionHeader.cmake.
>
> I will merge it if it helps create usable build version information.

I hereby attach my patch, please consider it.

Regards
Nick Østergaard

commit 7eba8d13ad9ad6cd87108f739001d929b93184e0
Author: Nick Østergaard <oe.nick@xxxxxxxxx>
Date:   Mon Jul 6 23:51:34 2015 +0200

    Add git support for the version string

diff --git a/CMakeLists.txt b/CMakeLists.txt
index 9230b9e..0da5bc7 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -692,8 +692,15 @@ if( KICAD_BUILD_VERSION )
     include( WriteVersionHeader )
     write_version_header( ${KICAD_BUILD_VERSION} )
 else()
+  if( EXISTS ${CMAKE_SOURCE_DIR}/.bzr )
     include( CreateBzrVersionHeader )
     create_bzr_version_header()
+  elseif( EXISTS ${CMAKE_SOURCE_DIR}/.git )
+    include( CreateGitVersionHeader )
+    create_git_version_header()
+  else()
+    message( STATUS "No supported VCS was found" )
+  endif()
 endif()
 
 if( EXISTS ${CMAKE_SOURCE_DIR}/include/config.h )
diff --git a/CMakeModules/CreateGitVersionHeader.cmake b/CMakeModules/CreateGitVersionHeader.cmake
new file mode 100644
index 0000000..c636764
--- /dev/null
+++ b/CMakeModules/CreateGitVersionHeader.cmake
@@ -0,0 +1,106 @@
+#
+#  This program source code file is part of KICAD, a free EDA CAD application.
+#
+#  Copyright (C) 2010 Wayne Stambaugh <stambaughw@xxxxxxxxxxx>
+#  Copyright (C) 2010-2015 Kicad Developers, see AUTHORS.txt for contributors.
+#
+#  This program is free software; you can redistribute it and/or
+#  modify it under the terms of the GNU General Public License
+#  as published by the Free Software Foundation; either version 2
+#  of the License, or (at your option) any later version.
+#
+#  This program is distributed in the hope that it will be useful,
+#  but WITHOUT ANY WARRANTY; without even the implied warranty of
+#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+#  GNU General Public License for more details.
+#
+#  You should have received a copy of the GNU General Public License
+#  along with this program; if not, you may find one here:
+#  http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
+#  or you may search the http://www.gnu.org website for the version 2 license,
+#  or you may write to the Free Software Foundation, Inc.,
+#  51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA
+#
+
+include( WriteVersionHeader )
+
+macro( create_git_version_header )
+    # If bzr is not found or an error occurs using the git commands to determine the repo
+    # version, set the build version string to "no-git"
+    set( KICAD_BUILD_VERSION "no-git" )
+
+    # Include Git support to automagically create version header file.
+    find_package( Git )
+
+    if( GIT_FOUND )
+        set( _Git_SAVED_LC_ALL "$ENV{LC_ALL}" )
+        set( ENV{LC_ALL} C )
+
+        # Get latest commit hash
+        execute_process(
+            COMMAND
+            ${GIT_EXECUTABLE} --no-pager log -1 HEAD
+            --pretty=format:%H
+            WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
+            OUTPUT_VARIABLE _git_LONG_HASH
+            ERROR_VARIABLE _git_log_error
+            RESULT_VARIABLE _git_log_result
+            OUTPUT_STRIP_TRAILING_WHITESPACE)
+
+        if( ${_git_log_result} EQUAL 0 )
+            execute_process(
+                COMMAND
+                ${GIT_EXECUTABLE} --no-pager log -1 HEAD
+                --pretty=format:%h
+                WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
+                OUTPUT_VARIABLE _git_SHORT_HASH
+                OUTPUT_STRIP_TRAILING_WHITESPACE)
+
+            execute_process(
+                COMMAND
+                ${GIT_EXECUTABLE} --no-pager log -1 HEAD
+                --pretty=format:%cn
+                WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
+                OUTPUT_VARIABLE _git_LAST_COMITTER
+                OUTPUT_STRIP_TRAILING_WHITESPACE)
+
+            execute_process(
+                COMMAND
+                ${GIT_EXECUTABLE} --no-pager log -1 HEAD
+                --pretty=format:%cd --date=short
+                WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
+                OUTPUT_VARIABLE _git_LAST_CHANGE_LOG
+                OUTPUT_STRIP_TRAILING_WHITESPACE)
+
+            execute_process(
+                COMMAND
+                ${GIT_EXECUTABLE} rev-list HEAD --count
+                --first-parent
+                WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
+                OUTPUT_VARIABLE _git_SERIAL
+                OUTPUT_STRIP_TRAILING_WHITESPACE)
+
+            message(STATUS "Git hash: ${_git_LONG_HASH}")
+
+            if( ${_git_log_result} EQUAL 0 )
+                string( REGEX REPLACE "^(.*\n)?revno: ([^ \n]+).*"
+                        "\\2" Kicad_REPO_REVISION "BZR ${_git_SERIAL}, Git ${_git_SHORT_HASH}" )
+                string( REGEX REPLACE "^(.*\n)?committer: ([^\n]+).*"
+                        "\\2" Kicad_REPO_LAST_CHANGED_AUTHOR "${_git_LAST_COMITTER}")
+                string( REGEX REPLACE "^(.*\n)?timestamp: [a-zA-Z]+ ([^ \n]+).*"
+                        "\\2" Kicad_REPO_LAST_CHANGED_DATE "${_git_LAST_CHANGE_LOG}")
+            endif()
+        endif()
+
+        set( ENV{LC_ALL} ${_Git_SAVED_LC_ALL} )
+    endif( GIT_FOUND )
+
+    # Check to make sure 'git' command did not fail.  Otherwise fallback
+    # to "no-git" as the revision.
+    if( Kicad_REPO_LAST_CHANGED_DATE )
+        string( REGEX REPLACE "^([0-9]+)\\-([0-9]+)\\-([0-9]+)" "\\1-\\2-\\3"
+                _kicad_git_date ${Kicad_REPO_LAST_CHANGED_DATE} )
+        set( KICAD_BUILD_VERSION "(${_kicad_git_date} ${Kicad_REPO_REVISION})" )
+    endif()
+    write_version_header( ${KICAD_BUILD_VERSION} )
+endmacro()